Archivo selectItems.egl completado después de la lección 3

Este código es la versión completada del archivo selectItems.egl después de la lección 3. Si ve muchos errores marcados por símbolos X rojos en el archivo, asegúrese de que su código coincida con este código:

Ejemplo

package programs;

import EGLDerbyDB.data.Item;
import EGLDerbyDB.primitivetypes.data.Price;

program selectItems type BasicProgram {}
  
  function main()
    try
      printExpensiveItems(200);
    onException(exception SQLException)
      handleDBException(exception);
    end
  end
  
  function printExpensiveItems(maxPrice Price in)
    
  tempItem Item;
  open expensiveItems for tempItem with
    #sql{
      select
        EGL.ITEM.ITEM_ID, EGL.ITEM.NAME, EGL.ITEM.IMAGE, 
        EGL.ITEM.PRICE, EGL.ITEM.DESCRIPTION
      from EGL.ITEM
      where
        EGL.ITEM.PRICE >= :maxPrice
      order by
        EGL.ITEM.ITEM_ID asc
    };
    
  forEach (tempItem)
    SysLib.writeStdout(tempItem.Name :: " " ::
      tempItem.Description :: " $" :: tempItem.Price);
  end
    
  end
  
  function handleDBException(exception SQLException)
    SysLib.writeStdout("Error de acceso a la base de datos."::
      "Consulte la sección Resolución de problemas");
    SysLib.writeStdout(exception.message);
  end
  
end

Volver a Lección 3: Gestionar un cursor con open y forEach.